home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / MISC / HCAL-27 / PWRSUPP.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1997-01-29  |  8.2 KB  |  279 lines
  1. 10  'PWRSUPP - Design Program - 01 JUL 91 rev. 29 SEP 96
  2. 20  IF EX$=""THEN EX$="EXIT"
  3. 30  IF PROG$=""THEN PROG$="pwrcct"
  4. 40  COMMON EX$,PROG$,EO,OV         'voltages for chaining to LM317 program
  5. 50  SCREEN 0,0,0:COLOR 7,0,1
  6. 60  KEY OFF:PI=3.14159
  7. 70  COLOR 7,0,1
  8. 80  X$=STRING$(80,32)
  9. 90  UL$=STRING$(80,205)
  10. 100  U$="###,###.##"
  11. 110  U1$="###.##":U2$="##"
  12. 120  DIM RES(12)       'standard resistors
  13. 130  '
  14. 140  DATA 10,12,15,18,22,27,33,39,47,56,68,82
  15. 150  FOR Z=1 TO 12:READ RES(Z):NEXT Z
  16. 160  '
  17. 170  '.....start
  18. 180  CLS
  19. 190  COLOR 15,2
  20. 200  PRINT " POWER SUPPLY DESIGN";
  21. 210  PRINT TAB(57)"by George Murphy VE3ERP ";
  22. 220  COLOR 1,0:PRINT STRING$(80,223);
  23. 230  COLOR 7,0
  24. 240  GOSUB 2010      'preface
  25. 250  GOSUB 2660      'screen dump
  26. 260  GOSUB 2480      'ripple note
  27. 270  GOSUB 2660      'screen dump
  28. 280  CLS:GOTO 330
  29. 290  '
  30. 300  '.....erase line
  31. 310  LOCATE 1:PRINT X$;:LOCATE 1:RETURN
  32. 320  '
  33. 330  '.....print diagram
  34. 340  LN=18               'start line
  35. 350  CN=13               'start column
  36. 360  GOSUB 1890          'print diagram
  37. 370  '
  38. 380  '.....transformer
  39. 390  COLOR 1,7:LOCATE 1,1
  40. 400  INPUT " ENTER: Intended DC output voltage..............";EO
  41. 410  COLOR 7,0
  42. 420  IF EO=0 THEN 400
  43. 430  OV=EO               'desired regulated voltage, if required
  44. 440  LOCATE 4:AC=117
  45. 450  PRINT" Transformer T1 primary..........";USING U$;AC;:PRINT" v.AC"
  46. 460  LOCATE 9
  47. 470  PRINT" Output voltage..................";USING U$;EO;:PRINT" v.DC";
  48. 480  PRINT "  (intended output =";OV;"v.DC)
  49. 490  LOCATE 5:ES=(EO+1.4)/1.41
  50. 500  PRINT" Transformer T1 secondary........";USING U$;ES;:PRINT" v.AC"
  51. 510  LOCATE 8:NL=ES*1.41
  52. 520  PRINT" No Load output..................";USING U$;NL;:PRINT" v.DC"
  53. 530  LOCATE 9
  54. 540  COLOR 0,7
  55. 550  PRINT" Full Load output................";USING U$;EO;:PRINT" v.DC"
  56. 560  COLOR 7,0
  57. 570  LOCATE 10:VR=100*(NL-EO)/EO
  58. 580  PRINT" Voltage regulation..............";USING U$;VR;:PRINT" %"
  59. 590  GOSUB 300
  60. 600  COLOR 1,7
  61. 610  PRINT " Do you want to re-do, using another transformer? (y/n)"
  62. 620  COLOR 7,0
  63. 630  Z$=INKEY$:IF Z$="n"OR Z$="N"THEN 730
  64. 640  IF Z$="y"OR Z$="Y"THEN 650 ELSE 630
  65. 650  LOCATE 5:PRINT X$;:LOCATE 8:PRINT X$;:LOCATE 9:PRINT X$;:LOCATE 10:PRINT X$;
  66. 660  GOSUB 300
  67. 670  COLOR 1,7
  68. 680  INPUT " ENTER: secondary voltage.......................";ES
  69. 690  COLOR 7,0
  70. 700  IF ES=0 THEN 660
  71. 710  EO=1.41*ES-1.4:GOTO 460
  72. 720  '
  73. 730  '.....current
  74. 740  GOSUB 300
  75. 750  COLOR 1,7
  76. 760  INPUT " ENTER: Required output current (amps)..........";IO
  77. 770  COLOR 7,0
  78. 780  IF IO=0 THEN 740
  79. 790  VA=CINT(ES*IO)
  80. 800  LOCATE 6:PRINT" Transformer T1 minimum rating...";USING U$;VA;:PRINT " VA."
  81. 810  RV=CINT(ES*2*1.41):D1=2*IO
  82. 820  LOCATE 7
  83. 830  PRINT" Rect.Diodes D1-D4 min.rating....";USING U$;RV;
  84. 840  PRINT " PRV";
  85. 850  LOCATE 7,50:PRINT USING U1$;D1;:PRINT" amp Full-Wave Bridge"
  86. 860  IT1=VA/117:IT2=VA/ES
  87. 870  LOCATE 4,50:PRINT USING U1$;IT1;:PRINT" amps"
  88. 880  LOCATE 5,50:PRINT USING U1$;IT2;:PRINT" amps"
  89. 890  LOCATE 11
  90. 900  PRINT" Output current..................";USING U$;IO;:PRINT" amps"
  91. 910  LOCATE 12:RO=EO/IO
  92. 920  PRINT" Load resistance & dissipation...";USING U$;RO;:PRINT" -"
  93. 930  PO=EO*IO
  94. 940  LOCATE 12,46:PRINT USING U$;PO;:PRINT" watts"
  95. 950  F1=(IO*EO/117)*1.2:IF F1<0.1 THEN F1=0.1
  96. 960  COLOR 0,7
  97. 970  LOCATE 3:PRINT" 117 volt AC input";
  98. 980  COLOR 7,0
  99. 990  PRINT" fuse F1 ......";USING U$;F1;:PRINT " amps, or nearest larger"
  100. 1000  '
  101. 1010  '.....filter capacitor
  102. 1020  GOSUB 300
  103. 1030  COLOR 1,7
  104. 1040  INPUT " ENTER: Maximum ripple % .......................";RP
  105. 1050  IF RP>100 OR RP=0 THEN COLOR 7,0:GOTO 1020
  106. 1060  COLOR 7,0
  107. 1070  T=1/120:ER=RP/100*EO*2.8
  108. 1080  C=INT((IO*T/ER)*10^6)
  109. 1090  WV=CINT(1.4*EO)
  110. 1100  LOCATE 13
  111. 1110  PRINT" Filter capacitor C1.............";USING U$;C;:PRINT" >F"
  112. 1120  LOCATE 13,50:PRINT USING U1$;WV;:PRINT" WVDC minimum"
  113. 1130  LOCATE 14
  114. 1140  PRINT" Ripple..........................";USING U$;RP;:PRINT" %"
  115. 1150  GOSUB 300
  116. 1160  COLOR 1,7
  117. 1170  PRINT " Do you want to re-do, using another capacitor? (y/n) "
  118. 1180  COLOR 7,0
  119. 1190  Z$=INKEY$:IF Z$="n"OR Z$="N"THEN 1280
  120. 1200  IF Z$="y"OR Z$="Y"THEN 1210 ELSE 1190
  121. 1210  GOSUB 300:COLOR 1,7
  122. 1220  INPUT " ENTER: Standard capacitor >F ..................";C
  123. 1230  COLOR 7,0
  124. 1240  IF C=0 THEN 1210
  125. 1250  LOCATE 13:PRINT X$;:LOCATE 14:PRINT X$;
  126. 1260  ER=IO*T*10^6/C:RP=ER*100/EO/2.8:GOTO 1090
  127. 1270  '
  128. 1280  '.....bleeder resistor
  129. 1290  RB=100*NL                   'RB=resistance  NL=no-load voltage
  130. 1300  M=1      'multiplier
  131. 1310  FOR Z=1 TO 12               'RES(1) to RES(12) are standard resistors
  132. 1320  IF RB>RES(Z)*M THEN 1350
  133. 1330  IF Z=1 THEN Z=13:M=M/10     'backup 1 step to allow z-1 in next line
  134. 1340  RB=RES(Z-1)*M:GOTO 1370
  135. 1350  NEXT Z
  136. 1360  M=M*10:GOTO 1310
  137. 1370  IB=NL/RB:PB=IB^2*RB:W=INT(5*PB+0.5)
  138. 1380  IF W<1 THEN W=1
  139. 1390  LOCATE 15
  140. 1400  PRINT" Bleeder resistor R1 ............";USING U$;RB;:PRINT" -"
  141. 1410  LOCATE 15,21:PRINT "(";USING U2$;W;:PRINT " watt )"
  142. 1420  LOCATE 15,50:PRINT USING U1$;IB*1000;:PRINT " ma.(typical)"
  143. 1430  '
  144. 1440  '.....pilot light
  145. 1450  EPL=EO-2:IPL=0.01:RPL=EPL/IPL
  146. 1460  M=10^5       'multiplier
  147. 1470  FOR Z=12 TO 1 STEP -1
  148. 1480  IF RPL<RES(Z)*M THEN 1500
  149. 1490  GOTO 1530
  150. 1500  NEXT Z
  151. 1510  M=M/10:GOTO 1470
  152. 1520  '
  153. 1530  ID5=EPL/(RES(Z)*M)*1000
  154. 1540  LOCATE 16:PRINT" LED pilot light D5..............";USING U$;2;
  155. 1550  PRINT " volts @"
  156. 1560  LOCATE 16,50:PRINT USING U1$;ID5;:PRINT " ma.(typical)"
  157. 1570  LOCATE 17:PRINT" LED resistor R2.................";USING U$;RES(Z)*M;
  158. 1580  PRINT " -"
  159. 1590  '
  160. 1600  '.....finish
  161. 1610  LOCATE 1
  162. 1620  COLOR 15,2
  163. 1630  PRINT" UNREGULATED POWER SUPPLY";TAB(57);"by George Murphy VE3ERP ";
  164. 1640  COLOR 1,0:PRINT STRING$(80,223);
  165. 1650  COLOR 7,0
  166. 1660  GOSUB 2660
  167. 1670  LOCATE 25,1:PRINT X$;
  168. 1680  '
  169. 1690  '.....LM317 diagram
  170. 1700  COLOR 14,0
  171. 1710  NC=CN+36:LOCATE LN
  172. 1720  LOCATE ,NC:PRINT "                         "
  173. 1730  LOCATE ,NC:PRINT "  VARPTRSOUNDSOUNDSOUNDSOUNDSOUNDCOLOR                "
  174. 1740  LOCATE ,NC:PRINT "SOUNDBSAVE<0xB4!>LM317BLOADSOUNDBSAVESOUNDSOUNDSOUNDBSAVESOUND + DEFSNGCOLOR    "
  175. 1750  LOCATE ,NC:PRINT " CALLCLSSOUNDSOUNDBSAVESOUNDSOUND' R3  CALL     CALL    "
  176. 1760  LOCATE ,NC:PRINT " C2  CLSSOUNDSOUNDSOUNDSOUND<0xB4!>  C3  REG. DC "
  177. 1770  LOCATE ,NC:PRINT " CALL        R4  CALL     CALL    "
  178. 1780  LOCATE ,NC:PRINT "SOUNDMOTORSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDMOTORSOUNDSOUNDSOUNDMOTORSOUND - DEFSNG'    ";
  179. 1790  '
  180. 1800  COLOR 14,6
  181. 1810  LOCATE 25,5
  182. 1820  PRINT " Do you want to run the LM317 voltage regulator ";
  183. 1830  PRINT "design program?   (y/n) ";
  184. 1840  COLOR 7,0
  185. 1850  Z$=INKEY$:IF Z$="n"THEN CLS:CHAIN PROG$
  186. 1860  IF Z$="y"THEN CLS:CHAIN"LM317"
  187. 1870  GOTO 1850
  188. 1880  '
  189. 1890  '.....diagram
  190. 1900  COLOR 0,7:LOCATE LN
  191. 1910  LOCATE ,CN:PRINT "   F1  S1  VARPTRSOUNDSOUNDCOLOR VARPTRSOUNDSOUNDSOUNDBSAVESOUNDSOUNDSOUNDCOLOR              "
  192. 1920  LOCATE ,CN:PRINT " SOUNDSOUND<UNK! {00F7}><UNK! {00F7}>SOUNDSOUND/ SOUNDSOUND<0xB4!>  BLOADSOUND'   D1  D2             "
  193. 1930  LOCATE ,CN:PRINT " AC  on/offCALLT1CALL   VARPTRSOUND<0xB4!>   BLOADSOUNDSOUNDBSAVESOUNDSOUNDBSAVESOUNDSOUNDBSAVESOUNDSOUND + "
  194. 1940  LOCATE ,CN:PRINT " SOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUND<0xB4!>  BLOADSOUNDCOLOR CALL D3  D4 CALL  CALL  R2    "
  195. 1950  LOCATE ,CN:PRINT "           CLSSOUNDSOUND' CLSSOUNDCALLSOUNDMOTORSOUNDSOUNDSOUND'  C1 R1 CALL  DC "
  196. 1960  LOCATE ,CN:PRINT "                  CALL        CALL  CALL  D5DEFDBL   "
  197. 1970  LOCATE ,CN:PRINT "                  CLSSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDMOTORSOUNDSOUNDMOTORSOUNDSOUNDMOTORSOUNDSOUND - ";
  198. 1980  COLOR 7,0
  199. 1990  RETURN
  200. 2000  '
  201. 2010  '.....preface
  202. 2020  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  203. 2030  TB=7    'tab for text
  204. 2040  PRINT TAB(TB);
  205. 2050  PRINT "  When you enter the intended output voltage of your power supply"
  206. 2060  PRINT TAB(TB);
  207. 2070  PRINT "the computer will display the basic specifications of the power"
  208. 2080  PRINT TAB(TB);
  209. 2090  PRINT "transformer required."
  210. 2100  PRINT TAB(TB);
  211. 2110  PRINT "  More than likely the secondary winding will be some oddball"
  212. 2120  PRINT TAB(TB);
  213. 2130  PRINT "voltage. The program gives you the option of selecting a standard"
  214. 2140  PRINT TAB(TB);
  215. 2150  PRINT "transformer with a secondary voltage higher than that specified."
  216. 2160  PRINT TAB(TB);
  217. 2170  PRINT "The output of the power supply will be higher than intended but"
  218. 2180  PRINT TAB(TB);
  219. 2190  PRINT "can be regulated to the exact intended voltage if you wish, by"
  220. 2200  PRINT TAB(TB);
  221. 2210  PRINT "adding an LM317 voltage regulator as part of the program. This is"
  222. 2220  PRINT TAB(TB);
  223. 2230  PRINT "much simpler than re-winding a surplus transformer, as we had to"
  224. 2240  PRINT TAB(TB);
  225. 2250  PRINT "do in the Goode Olde Dayes....."
  226. 2260  PRINT TAB(TB);
  227. 2270  PRINT "  The size of the filter capacitor depends on the maximum tolerable"
  228. 2280  PRINT TAB(TB);
  229. 2290  PRINT "DC ripple, ranging from about 0.01% for critical audio applications"
  230. 2300  PRINT TAB(TB);
  231. 2310  PRINT "(e.g. VFOs, receivers) to 100% where DC smoothing is not required."
  232. 2320  PRINT TAB(TB);
  233. 2330  PRINT "Low ripple power supplies require large filter capacitors."
  234. 2340  PRINT TAB(TB);
  235. 2350  PRINT "  The computer will probably specify a filter capacitor with a non-"
  236. 2360  PRINT TAB(TB);
  237. 2370  PRINT "standard value. You have the option of changing this to a standard"
  238. 2380  PRINT TAB(TB);
  239. 2390  PRINT "value close to the computed value. Capacitors can be ganged in"
  240. 2400  PRINT TAB(TB);
  241. 2410  PRINT "parallel to obtain capacitances greater than the highest value"
  242. 2420  PRINT TAB(TB);
  243. 2430  PRINT "available in a single standard capacitor (e.g if 10,500 pF is"
  244. 2440  PRINT TAB(TB);
  245. 2450  PRINT "needed, five 2200 pF capacitors can be ganged to make 11,000 pF)."
  246. 2460  RETURN
  247. 2470  '
  248. 2480  '.....ripple notes
  249. 2490  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  250. 2500  PRINT TAB(TB)"Typical recommended ripple levels:"
  251. 2510  PRINT TAB(TB)"THENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHEN"
  252. 2520  PRINT
  253. 2530  PRINT TAB(TB)"CW transmitter multipliers & amplifiers........ 5% max."
  254. 2540  PRINT
  255. 2550  PRINT TAB(TB)"Linear amplifier plate voltage................. 3% max."
  256. 2560  PRINT
  257. 2570  PRINT TAB(TB)"Linear amplifier bias supply................... 1% max."
  258. 2580  PRINT
  259. 2590  PRINT TAB(TB)"VFOs, speech amplifiers and receivers.......... 0.01% - 0.1%"
  260. 2600  PRINT
  261. 2610  PRINT TAB(TB)"Non-critical audio devices..................... 1% - 10%"
  262. 2620  PRINT
  263. 2630  PRINT TAB(TB)"Devices not requiring DC smoothing............. 10% - 100%"
  264. 2640  RETURN
  265. 2650  '
  266. 2660  'HARDCOPY
  267. 2670  GOSUB 2780:LOCATE 25,2:COLOR 14,6
  268. 2680  PRINT " Press 1 to print screen, 2 to print screen & ";
  269. 2690  PRINT "advance paper, or 3 to continue.";:COLOR 7,0
  270. 2700  Z$=INKEY$:IF Z$="3"THEN GOSUB 2780:RETURN
  271. 2710  IF Z$="1"OR Z$="2"THEN GOSUB 2780:GOTO 2730
  272. 2720  GOTO 2700
  273. 2730  FOR QX=1 TO 24:FOR QY=1 TO 80
  274. 2740  LPRINT CHR$(SCREEN(QX,QY));
  275. 2750  NEXT QY:NEXT QX
  276. 2760  IF Z$="2"THEN LPRINT CHR$(12)
  277. 2770  GOTO 2670
  278. 2780  LOCATE 25,1:PRINT STRING$(80,32);:RETURN
  279.